* (C) Copyright Efficient Power Conversion Corporation. All rights reserved.
*****************************************************************************
* Version History:
* 1.00: 06/05/2023 - Initial Model Creation

.subckt EPC2619 gatein drainin sourcein
.param  si={aWg} so={aWg} sr={aWg}
.param  aWg={Wg*1E-3} Wg=1092000 A1={2.905e-02*aWg} k2=1.597e+00 k3=9.000e-02 rpara=2.398e-03
+      rpara_s_factor=3.669e-01 aITc=4.997e-03 arTc=-3.532e-03 k2Tc=1.231e-03
+      x0_0=3.185e+00 x0_0_TC=-1.274e-03 x0_1=1.000e-03 x0_1_TC=-1.000e-01
+      dgs1=4.3e-07 dgs2=2.6e-13 dgs3=0.8 dgs4=0.23
+      ags1={1.060e-12*si} ags2={3.020e-13*si} ags3=1.667e+00 ags4=1.640e-01
+      ags5={0.000e+00*si} ags6=7.480e+01 ags7=1.055e+01
+      agd1={1.370e-15*sr} agd2={1.670e-13*sr} agd3=-5.538e-01 agd4=4.884e+00
+      agd5={3.120e-15*sr} agd6=-6.439e+01 agd7=4.289e+00 agd8={0.000e+00*sr}
+      agd9=-2.026e+01 agd10=8.900e-01
+      asd1={2.650e-13*so} asd2={4.316e-13*so} asd3=-1.250e+01 asd4=7.707e+00
+      asd5={9.003e-14*so} asd6=-6.750e+01 asd7=1.108e+01 asd8={1.596e-13*so}
+      asd9=-1.000e+01 asd10=1.206e+00
+      rg_value=0.44

rd drainin drain ((1-rpara_s_factor)*rpara*(1-arTc*(Temp-25)))
rs sourcein source (rpara_s_factor*rpara*(1-arTc*(Temp-25)))
rg gatein gate (rg_value)


*Large resistors to aid convergence
rcsdconv drain source (100000Meg/aWg)
rcgsconv gate source (100000Meg/aWg)
rcgdconv gate drain (100000Meg/aWg)

gswitch drain source cur='if(v(drain,source)>0,
+	(A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(Temp-25))))/k3))*
+	v(drain,source)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,source))*v(drain,source)) ),
+	(-A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(Temp-25))))/k3))*
+	v(source,drain)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,drain))*v(source,drain)) ) ) '


ggsdiode gate source cur='if( v(gate,source) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

ggddiode gate drain cur='if( v(gate,drain) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

cgs gate source ags1
gcgs gate source chg='0.5*ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+	ags5*ags7*log(1+exp((v(source,drain)-ags6)/ags7))'

cgd gate drain agd1
gcgd gate drain chg='0.5*ags2*ags4*log(1+exp((v(gate,drain)-ags3)/ags4))+
+	agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+
+	agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7))+
+	agd8*agd10*log(1+exp((v(gate,drain)-agd9)/agd10))'

csd source drain asd1
gcsd source drain chg='asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+	asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7))+
+	asd8*asd10*log(1+exp((v(source,drain)-asd9)/asd10))'

.ends