//* 1.01: 05/28/2019 - Fixed a typo

simulator lang=spectre

subckt epc1010 (gatein drainin sourcein)


parameters aWg=599  k1=28 k2=1.85 k4=1 
+	ags1=4.06e-10 ags2=4.69e-10 ags3=4.28e-12 ags4=1.25 ags5=.156 
+	agd1=3.15e-11  agd2=1.24e-10 agd3=-1.95 agd4=4.01 agd5=.022e-12
+	asd1=130E-12 asd2=300E-12 asd3=-100 asd4=60 asd5=180E-12 asd6=-15 asd7=3.0
+	dgs1=4.3e-7 dgs2=2.6e-13 dgs3=.8 dgs4=.23  
+	aITc=.0025 aSTc=.0005


rd (drainin drain) resistor r=.0057
rs (source sourcein) resistor r=.0001
rg (gatein gate) resistor r=(.6*1077/aWg)


gswitch drain source bsource i=(1-aITc*(temp-25))*k1*0.5*(1+tanh(1000*v(drain,source)))*
+	 ags5*log(1.0+exp((v(gate,source)-k2)/ags5))*	
+	(1-exp(-(k4*(1-aSTc*(temp-25)))*v(drain,source)))

gswitchr drain source bsource i=(-1*(1-aITc*(temp-25))*k1*0.5*(1+tanh(1000*v(source,drain)))*
+	ags5*log(1.0+exp((v(gate,drain)-k2)/ags5))*
+	(1-exp(-(k4*(1-aSTc*(temp-25)))*v(source,drain))))

ggsdiode gate source bsource i=0.5*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1))

ggddiode gate drain bsource i=0.5*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1))


C_GS  (gate source) bsource c=(ags1)  
G_CGS1 (gate source) bsource q=(ags2*ags5*log(1.0 + exp( (v(gate,source)-ags4)/ags5 ) ) + 
+	ags3*0.5*v(gate,source)*v(gate,source) )
 
C_GD  (gate drain) bsource c=(agd1)  
G_CGD1 (gate drain) bsource q=(agd2*agd4*log(1.0 + exp( (v(gate,drain)-agd3)/agd4 ) ) + 
+	agd5*0.5*v(gate,drain)*v(gate,drain) ) 

C_SD  (source drain) bsource c=(asd1) 
G_CSD1 (source drain) bsource q=(asd2*asd4*log(1 + exp( (v(source,drain)-asd3)/asd4) ) + 
+	asd5*asd7*log( 1 + exp((v(source,drain)-asd6)/asd7)  ) )

ends epc1010