// (C) Copyright Efficient Power Conversion Corporation. All rights reserved.
// **************************************************************************
//* Version History:
//* 1.02: Added Copyright Statement
//* 1.03: 05/28/2019 - Fixed a typo

simulator lang=spectre

subckt epc2012 (gatein drainin sourcein)


parameters aWg=146 A1=4.3309 k2=2.1 k3=0.12 rpara=0.06 
+      aITc=0.0043 arTc=-0.0068 ax0Tc=0.0028 x0_0=0.0 x0_1=0.45
+      dgs1=4.3e-7 dgs2=2.6e-13 dgs3=.8 dgs4=.23	  
+      ags1=1.2450e-010 ags2=7.9121e-011 ags3=1.6339e+000 ags4=2.0698e-001
+      ags5=-1.5134e-011 ags6=-9.3226e+000 ags7=3.9756e+000
+      agd1=3.0183e-012 agd2=2.1636e-011 agd3=-6.9085e+000 agd4=4.3081e+000
+      agd5=1.1765e-012 agd6=-8.2032e+001 agd7=1.2520e+001
+      asd1=6.0088e-011 asd2=1.2843e-010 asd3=-1.6361e+001 asd4=1.9825e+000
+      asd5=4.3202e-011 asd6=-6.0821e+001 asd7=3.2895e+001


rd (drainin drain) resistor r=(0.75*rpara*(1-arTc*(temp-25)))
rs (sourcein source) resistor r=(0.25*rpara*(1-arTc*(temp-25)))
rg (gatein gate) resistor r=(.6)

rcsdconv (drain source) resistor r=(1E9/aWg)
rcgsconv (gate source) resistor r=(1E9/aWg)
rcgdconv (gate drain) resistor r=(1E9/aWg)

gswitch drain source bsource i=( (v(drain,source)>0) ? 
+	(A1*(1-aITc*(temp-25))*log(1.0+exp((v(gate,source)-k2)/k3))* 
+	v(drain,source)/(1 + max((1-ax0Tc*(temp-25))*(x0_0+x0_1*v(gate,source)),0.2)*v(drain,source)) ) : 
+	(-A1*(1-aITc*(temp-25))*log(1.0+exp((v(gate,drain)-k2)/k3))* 
+	v(source,drain)/(1 + max((1-ax0Tc*(temp-25))*(x0_0+x0_1*v(gate,drain)),0.2)*v(source,drain)) ) )

ggsdiode gate source bsource i=( (v(gate,source)>10) ? 
+	(0.5*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))) : 
+	(0.5*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1)))  )

ggddiode gate drain bsource i=( (v(gate,drain)>10) ? 
+	(0.5*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))) : 
+	(0.5*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1))) )


C_GS  (gate source) bsource c=(ags1)  
G_CGS1 (gate source) bsource q=(0.5*ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+	ags5*ags7*log(1+exp((v(source,drain)-ags6)/ags7)) )

C_GD  (gate drain) bsource c=(agd1)  
G_CGD1 (gate drain) bsource q=(0.5*ags2*ags4*log(1+exp((v(gate,drain)-ags3)/ags4))+
+	agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7)) )

C_SD  (source drain) bsource c=(asd1) 
G_CSD1 (source drain) bsource q=(asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+	asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7)) )


ends epc2012