//* (C) Copyright Efficient Power Conversion Corporation. All rights reserved.
//*****************************************************************************
//* Version History:
//* 1.00: 06/04/2026 - Initial Model Creation



simulator lang=spectre

subckt EPC2378 (gatein drainin sourcein)
parameters  si=4754 so=4754 sr=4754
parameters aWg=4754 A1=(3.555e-02*aWg) k2=1.808e+00 k3=9.000e-02 rpara=2.394e-04
+      rpara_s_factor=2.759e-01 aITc=1.898e-03 arTc=-9.170e-03 k2Tc=4.500e-04
+      x0_0=8.455e+00 x0_0_TC=1.060e-05 x0_1=-2.000e-01 x0_1_TC=5.000e-02
+      dgs1=4.3e-07 dgs2=2.6e-13 dgs3=0.8 dgs4=0.23
+      ags1=(1.174e-12*si) ags2=(6.409e-14*si) ags3=2.287e+00 ags4=4.714e-01					
+      ags5=(8.247e-14*si) ags6=2.240e+00 ags7=1.895e-01										
+      agd1=(6.367e-15*sr) agd2=(4.426e-15*sr) agd3=-1.581e+01 agd4=4.230e+00					
+      agd5=(6.252e-14*sr) agd6=-2.079e+00 agd7=1.430e+00 agd8=(2.034e-14*sr)					
+      agd9=-6.023e+00 agd10=6.830e-01 agd11=(8.366e-14*sr) agd12=2.250e+01					
+      agd13=5.384e-01							
+      asd1=(1.868e-13*so) asd2=(3.041e-13*so) asd3=-1.831e+00 asd4=1.067e+01					
+      asd5=(1.210e-13*so) asd6=-5.307e+00 asd7=6.604e-01 asd8=(1.777e-13*so)					
+      asd9=-7.102e+00 asd10=3.590e-01 asd11=(1.682e-14*so) asd12=-1.015e+01					
+      asd13=1.422e+00										
+      rg_value=0.1

rd (drainin drain) resistor r=((1-rpara_s_factor)*rpara*(1-arTc*(temp-25)))
rs (sourcein source) resistor r=(rpara_s_factor*rpara*(1-arTc*(temp-25)))
rg (gatein gate) resistor r=(rg_value)

rcsdconv (drain source) resistor r=(1E9/aWg)
rcgsconv (gate source) resistor r=(1E9/aWg)
rcgdconv (gate drain) resistor r=(1E9/aWg)

gswitch drain source bsource i=( (v(drain,source)>0) ? 
+	(A1*(1-aITc*(temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(temp-25))))/k3))* 
+	v(drain,source)/(1 + (x0_0*(1-x0_0_TC*(temp-25))+x0_1*(1-x0_1_TC*(temp-25))*v(gate,source))*v(drain,source))) :
+	(-A1*(1-aITc*(temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(temp-25))))/k3))* 
+	v(source,drain)/(1 + (x0_0*(1-x0_0_TC*(temp-25))+x0_1*(1-x0_1_TC*(temp-25))*v(gate,drain))*v(source,drain))) )

ggsdiode gate source bsource i=( (v(gate,source)>10) ? 
+	(0.125*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))) : 
+	(0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1))) )

ggddiode gate drain bsource i=( (v(gate,drain)>10) ? 
+	(0.125*aWg/1077*(dgs1*(exp((10.0)/dgs3)-1)+dgs2*(exp((10.0)/dgs4)-1))) : 
+	(0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1))) )


C_GS  (gate source) bsource c=(ags1)  
G_CGS1 (gate source) bsource q=(ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+	ags5*ags7*log(1+exp((v(gate,source)-ags6)/ags7)) )

C_GD  (gate drain) bsource c=(agd1)  
G_CGD1 (gate drain) bsource q=(agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+
+	agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7))+
+	agd8*agd10*log(1+exp((v(gate,drain)-agd9)/agd10))+
+	agd11*agd13*log(1+exp((v(gate,drain)-agd12)/agd13)) )

C_SD  (source drain) bsource c=(asd1) 
G_CSD1 (source drain) bsource q=(asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+	asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7))+ 
+	asd8*asd10*log(1+exp((v(source,drain)-asd9)/asd10))+
+	asd11*asd13*log(1+exp((v(source,drain)-asd12)/asd13))    )

ends EPC2378