* (C) Copyright Efficient Power Conversion Corporation. All rights reserved.
*****************************************************************************
* Version History:
* 1.00: 06/05/2019 - Initial Model Creation
* 1.01: 10/14/2020 - Updated the Model from the Preliminary Version

.subckt EPC2059 gatein drainin sourcein
.param  si={aWg*8.500e-04} so={aWg*5.100e-03} sr={aWg}
.param  aWg={Wg*1E-3} Wg=681000 A1={3.853e-02*aWg} k2=1.759e+00 k3=9.000e-02 rpara=5.684e-03
+	rpara_s_factor=3.086e-01 aITc=3.000e-03 arTc=-6.500e-03 k2Tc=6.000e-04
+	x0_0=4.270e+00 x0_0_TC=-4.000e-03 x0_1=1.595e-02 x0_1_TC=0.000e+00
+	dgs1=4.3e-07 dgs2=2.6e-13 dgs3=0.8 dgs4=0.23
+	ags1={1.092e-09*si} ags2={5.570e-10*si} ags3=1.447e+00 ags4=1.829e-01
+	ags5={6.219e-10*si} ags6=2.590e-01 ags7=3.393e-03
+	agd1={1.411e-15*sr} agd2={8.924e-14*sr} agd3=-6.560e+00 agd4=2.786e+00
+	agd5={2.351e-14*sr} agd6=-1.126e+01 agd7=2.316e+01 agd8={1.446e-14*sr}
+	agd9=-1.614e+01 agd10=1.229e+00
+	asd1={6.144e-11*so} asd2={6.441e-11*so} asd3=-4.747e+01 asd4=3.175e+01
+	asd5={5.062e-11*so} asd6=-1.686e+01 asd7=1.479e+00 asd8={5.073e-11*so}
+	asd9=-1.532e+01 asd10=8.691e+00
+	rg_value=0.5

rd drainin drain ((1-rpara_s_factor)*rpara*(1-arTc*(Temp-25)))
rs sourcein source (rpara_s_factor*rpara*(1-arTc*(Temp-25)))
rg gatein gate (rg_value)


*Large resistors to aid convergence
rcsdconv drain source (100000Meg/aWg)
rcgsconv gate source (100000Meg/aWg)
rcgdconv gate drain (100000Meg/aWg)

gswitch drain source cur='if(v(drain,source)>0,
+	(A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+	v(drain,source)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,source))*v(drain,source)) ),
+	(-A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+	v(source,drain)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,drain))*v(source,drain)) ) ) '


ggsdiode gate source cur='if( v(gate,source) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

ggddiode gate drain cur='if( v(gate,drain) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

cgs gate source ags1
gcgs gate source chg='0.5*ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+	ags5*ags7*log(1+exp((v(source,drain)-ags6)/ags7))'

cgd gate drain agd1
gcgd gate drain chg='0.5*ags2*ags4*log(1+exp((v(gate,drain)-ags3)/ags4))+
+	agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+
+	agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7))+
+	agd8*agd10*log(1+exp((v(gate,drain)-agd9)/agd10))'

csd source drain asd1
gcsd source drain chg='asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+	asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7))+
+	asd8*asd10*log(1+exp((v(source,drain)-asd9)/asd10))'

.ends