* (C) Copyright Efficient Power Conversion Corporation. All rights reserved.
*****************************************************************************
* Version History:
* 1.00: 06/07/2021 - Initial Model Creation

.subckt EPC2065 gatein drainin sourcein
.param  si={aWg*7.500e-04} so={aWg*4.100e-03} sr={aWg}
.param  aWg={Wg*1E-3} Wg=1435000 A1={2.360e-02*aWg} k2=1.987e+00 k3=9.000e-02 rpara=1.796e-03
+	rpara_s_factor=2.503e-01 aITc=3.000e-03 arTc=-1.000e-02 k2Tc=6.000e-04
+	x0_0=6.199e+00 x0_0_TC=-3.000e-03 x0_1=-9.127e-01 x0_1_TC=0.000e+00
+	dgs1=4.3e-07 dgs2=2.6e-13 dgs3=0.8 dgs4=0.23
+	ags1={9.813e-10*si} ags2={3.797e-10*si} ags3=1.871e+00 ags4=3.403e-01
+	ags5={3.340e-12*si} ags6=-5.234e+00 ags7=2.619e+01
+	agd1={2.156e-15*sr} agd2={1.073e-13*sr} agd3=-3.024e+00 agd4=4.061e+00
+	agd5={1.362e-14*sr} agd6=-1.188e+01 agd7=3.001e+01 agd8={2.773e-14*sr}
+	agd9=-1.400e+01 agd10=1.326e+00
+	asd1={6.095e-11*so} asd2={8.613e-11*so} asd3=-1.587e+01 asd4=1.874e+00
+	asd5={4.307e-12*so} asd6=-2.956e+01 asd7=3.963e+00 asd8={5.492e-11*so}
+	asd9=-3.554e+01 asd10=3.338e+01
+	rg_value=0.4

rd drainin drain ((1-rpara_s_factor)*rpara*(1-arTc*(Temp-25)))
rs sourcein source (rpara_s_factor*rpara*(1-arTc*(Temp-25)))
rg gatein gate (rg_value)


*Large resistors to aid convergence
rcsdconv drain source (100000Meg/aWg)
rcgsconv gate source (100000Meg/aWg)
rcgdconv gate drain (100000Meg/aWg)

gswitch drain source cur='if(v(drain,source)>0,
+	(A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+	v(drain,source)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,source))*v(drain,source)) ),
+	(-A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+	v(source,drain)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,drain))*v(source,drain)) ) ) '


ggsdiode gate source cur='if( v(gate,source) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

ggddiode gate drain cur='if( v(gate,drain) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

cgs gate source ags1
gcgs gate source chg='0.5*ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+	ags5*ags7*log(1+exp((v(source,drain)-ags6)/ags7))'

cgd gate drain agd1
gcgd gate drain chg='0.5*ags2*ags4*log(1+exp((v(gate,drain)-ags3)/ags4))+
+	agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+
+	agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7))+
+	agd8*agd10*log(1+exp((v(gate,drain)-agd9)/agd10))'

csd source drain asd1
gcsd source drain chg='asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+	asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7))+
+	asd8*asd10*log(1+exp((v(source,drain)-asd9)/asd10))'

.ends