* (C) Copyright Efficient Power Conversion Corporation. All rights reserved.
*****************************************************************************
* Version History:
* 1.00: 10/01/2019 - Initial Model Creation

.subckt EPC2216 gatein drainin sourcein
.param  si=1.122e-01 so=5.517e-01 sr=1.870e+02
.param  aWg=187 A1={6.636e-02*aWg} k2=1.983e+00 k3=9.000e-02 rpara=1.752e-02
+	rpara_s_factor=3.671e-01 aITc=3.500e-03 arTc=-6.200e-03 k2Tc=6.800e-04
+	x0_0=5.112e+00 x0_0_TC=-1.000e-03 x0_1=5.175e-01 x0_1_TC=0.000e+00
+	dgs1=4.3e-07 dgs2=2.6e-13 dgs3=0.8 dgs4=0.23
+	ags1={6.684e-10*si} ags2={3.922e-10*si} ags3=1.708e+00 ags4=2.000e-01
+	ags5={0.000e+00*si} ags6=0.000e+00 ags7=1.000e+01
+	agd1={5.348e-15*sr} agd2={2.144e-13*sr} agd3=1.000e-01 agd4=2.000e+01
+	agd5={6.310e-14*sr} agd6=5.000e+00 agd7=1.000e+01 agd8={5.390e-14*sr}
+	agd9=1.280e+00 agd10=1.500e+00
+	asd1={7.287e-11*so} asd2={3.064e-11*so} asd3=1.000e-01 asd4=2.000e+01
+	asd5={2.719e-12*so} asd6=-5.000e-02 asd7=2.500e-01 asd8={0.000e+00*so}
+	asd9=1.000e+00 asd10=1.000e+00
+	rg_value=0.5

rd drainin drain ((1-rpara_s_factor)*rpara*(1-arTc*(Temp-25)))
rs sourcein source (rpara_s_factor*rpara*(1-arTc*(Temp-25)))
rg gatein gate (rg_value)


*Large resistors to aid convergence
rcsdconv drain source (100000Meg/aWg)
rcgsconv gate source (100000Meg/aWg)
rcgdconv gate drain (100000Meg/aWg)

gswitch drain source cur='if(v(drain,source)>0,
+	(A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,source)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+	v(drain,source)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,source))*v(drain,source)) ),
+	(-A1*(1-aITc*(Temp-25))*log(1.0+exp((v(gate,drain)-(k2*(1-k2Tc*(Temp-25))))/k3))* 
+	v(source,drain)/(1 + (x0_0*(1-x0_0_TC*(Temp-25))+x0_1*(1-x0_1_TC*(Temp-25))*v(gate,drain))*v(source,drain)) ) ) '


ggsdiode gate source cur='if( v(gate,source) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,source))/dgs3)-1)+dgs2*(exp((v(gate,source))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

ggddiode gate drain cur='if( v(gate,drain) < 10,
+	0.125*aWg/1077*(dgs1*(exp((v(gate,drain))/dgs3)-1)+dgs2*(exp((v(gate,drain))/dgs4)-1)),
+	0.125*aWg/1077*(dgs1*(exp((10)/dgs3)-1)+dgs2*(exp((10)/dgs4)-1)) )'

cgs gate source ags1
gcgs gate source chg='0.5*ags2*ags4*log(1+exp((v(gate,source)-ags3)/ags4))+
+	ags5*ags7*log(1+exp((v(source,drain)-ags6)/ags7))'

cgd drain gate agd1
gcgd drain gate chg='0.5*ags2*ags4*log(1+exp((v(gate,drain)-ags3)/ags4))+
+	agd2*agd4*log(1+exp((v(gate,drain)-agd3)/agd4))+
+	agd5*agd7*log(1+exp((v(gate,drain)-agd6)/agd7))+
+	agd8*agd10*log(1+exp((v(gate,drain)-agd9)/agd10))'

csd source drain asd1
gcsd source drain chg='asd2*asd4*log(1+exp((v(source,drain)-asd3)/asd4))+
+	asd5*asd7*log(1+exp((v(source,drain)-asd6)/asd7))+
+	asd8*asd10*log(1+exp((v(source,drain)-asd9)/asd10))'

.ends